;  Программа подключения на БК0011м ОЗУ по адресам 140000-170000. 
	;По RESET (а также запросу RAM-BIOS'а 'EXIT') режим сохраняется.
	;(c) RSC, 1998-2002

        EMT     14
        MOV     #TXT,R1
        CLR     R2
        EMT     20
        CMPB    @#177717,#200
        BEQ     1BK10
        MOV     #BLK,R1
        MOV     #20,R2
        CLR     R0
        JSR     R5,@#167521
        TST     R0
        BEQ     1ER
        BMI     2ER

        CLR     R0
        MOV     #BLK,R1
        MOV     #"RR,(R1)
        MOV     #4000,2(R1)
        MOV     #100020,R2
        JSR     R5,@#167521
        TST     R0
        BEQ     1ER
        BMI     2ER

        CLR     R0
        MOV     #BLK,R1
        MOV     (PC)+,(R1)
        .BYTE   0,'$
        MOV     #21,2(R1)
        BIS     #220,4(R1)
        CLR     12(R1)
        MOV     #4,10(R1)
        CLR     R2
        JSR     R5,@#167521
        TST     R0
        BEQ     1PREDUP
        BMI     2PREDUP

        MOV     #RUN,R0
        MOV     #0,R1
        MOV     #21,R2
        JSR     R5,@#167520
        .WORD   376
        .BYTE   0,'$
        TST     R2
        BEQ     3ER
        BR      33
1PREDUP:
        MOV     #TXT3,R1
        CLR     R2
        EMT     20
        BR      33
2PREDUP:
        MOV     #TXT4,R1
        CLR     R2
        EMT     20

33:     MOV     #140000,R0
        MOV     #14000,R1
        MOV     #BUF,R2
        MOV     (R0)+,(R2)+
        SOB     R1,.-2

        MOV     #BUF+20000,R0
        MOV     #0,R1
        MOV     #4000,R2
        JSR     R5,@#167520
        .WORD   377,"RR
        TST     R2
        BEQ     3ER

        MOV     #BUF,R0
        MOV     #0,R1
        MOV     #10000,R2
        JSR     R5,@#167520
        .WORD   377,"MR
        TST     R2
        BEQ     3ER

        JSR     R5,@#167524
        .WORD   120020,2160
        MOV     R0,.+14
        MOV     #40,R0
        JSR     R5,@#167525
        .WORD   0,2160

        JSR     R5,@#167527
1BK10:  MOV     #TXT6,R1
        BR      1ERR$
1ER:    MOV     #TXT1,R1
        BR      1ERR$
2ER:    MOV     #TXT2,R1
        BR      1ERR$
3ER:    MOV     #TXT5,R1
        BR      1ERR$
1ERR$:  CLR     R2
        EMT     20
        EMT     6
        EMT     130
RUN:    JSR     R5,@#167527
        .ASCIZ  /Обработчик RESET+ничего: EXIT/
        .EVEN

BLK:    .WORD   "MR,10000,4+10+2,0,0,0,100000,0
TXT:    .ASCII  /  Программа подключения на БК0011м ОЗУ по ад-/
        .BYTE   12
        .ASCII  /ресам 140000-170000. По RESET (а также запро-/
        .BYTE  12
        .ASCII  /су RAM-BIOS'а 'EXIT') режим сохраняется./<12>
        .ASCIZ  /(c) RSC, 1998/<12><12>
TXT2:   .ASCIZ  /Модуль уже существует/
TXT1:   .ASCIZ  /Невозможно создать модуль/
TXT3:   .ASCIZ  /Reset невозможно обработать/
TXT4:   .ASCIZ  /Reset уже обрабатывается/
TXT5:   .ASCIZ  /Невозможно переслать модуль/
TXT6:   .ASCIZ  /Данная программа предназначена для БК0011м/
        .EVEN
BUF:    .END